Форум Flasher.ru - ActionScript 3 Tips and Tricks

Страница 9 из 13

Показывать 40 сообщений этой темы на одной странице

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- Статьи (http://www.flasher.ru/forum/forumdisplay.php?f=101)

- - ActionScript 3 Tips and Tricks (http://www.flasher.ru/forum/showthread.php?t=85645)

MerlinTwi

02.11.2006 18:32

86. Больше нет класса Color, используйте ColorTransform

В ActionScript 3 больше нет класса Color, взамен можно использовать класс ColorTransform (flash.geom.ColorTransform). По сути это тот же класс ColorTransform что был и в Flash Player 8, только свойство rgb было переименовано в color.

Код:

// создаем красный квадрат

// рисуем черный

var square:Shape = new Shape();

square.graphics.beginFill(0x000000);

square.graphics.drawRect(0, 0, 100, 100);

// и делаем цветокоррекцию с помощью ColorTransform

var colorTransform:ColorTransform = square.transform.colorTransform;

colorTransform.color = 0xFF0000;

square.transform.colorTransform = colorTransform;



addChild(square);

MerlinTwi

02.11.2006 18:45

88. Ошибки: try..catch..finally

Для перехвата ошибок вы можете использовать (try..catch..finally statement).

Код:

try {

     // statements

} catch (error:Error) {

     // statements

} finally {

     // statements

}

Первый блок внутри try – это место где ожидается возникновение ошибки. Далее идет блок catch который будет выполнится если в блоке try произойдет ошибка. Блоков catch может быть несколько с указанием на какой тип ошибки реагировать. И в конце идет блок finally, который выполняется после try и catch и выполняется всегда, даже если ошибка не была поймана в catch и дальнейшее выполнение кода будет прервано, или же было вызвано return, блок finally все равно выполняется.
Пример:

Код:

try {

    var value:* = new Array();

    trace(value.getChildAt(0));

    

} catch(error:IOErrorEvent) {

    trace("IOErrorEvent catch: " + error);

    

} catch(error:TypeError) {

    trace("TypeError catch: " + error);

    

} catch(error:Error) {

    trace("Error catch: " + error);

    

} finally {

    trace("Finally!");

}



trace("Continuing with script...");

Результат выполнения:

Код:

TypeError catch: TypeError: Error #1006: getChildAt is not a function.

Finally!

Continuing with script...

В соответствии с типом ошибки выполнился блок catch(error:TypeError), и выполнение скрипта продолжилось.
Что произойдет, если не будет блока catch соответствующего типу возникшей ошибки:

Код:

try {

    var value:* = new Array();

    trace(value.getChildAt(0));

    

} catch(error:IOErrorEvent) {

    trace("IOErrorEvent catch: " + error);

    

} finally {

    trace("Finally!");

}



trace("Continuing with script...");

Результат выполнения:

Код:

Finally!

TypeError: Error #1006: getChildAt is not a function.

        at Timeline0_a24dfc5f2aa9864b9d4de27c9fa097db/::frame1()

Ошибка не была поймана, выполнился только блок finally и дальнейшее выполнение скрипта было прервано.

MerlinTwi

02.11.2006 19:03

89. Перехват асинхронных ошибок

Иногда ошибка может произойти намного позже того, как была вызвана функция ее спровоцировавшая. Например, загрузка внешнего контента с помощью (flash.net.URLLoader). После вызова URLLoader.load с неправильным URL, плеер продолжит выполнение дальнейшего кода, а непосредственно процесс загрузки начнется позже, и только тогда возникнет ошибка. В таких случаях использование блока try..catch..finally не поможет, т.к. в самом коде в момент выполнения ошибки нет.
Пример:

Код:

var loader:URLLoader = new URLLoader();

loader.load(new URLRequest("Invalid XML URL"));

trace("Continuing with script...");

Результат выполнения:

Код:

Continuing with script...

Error #2044: Unhandled ioError:. text=Error #2032: Stream Error. URL: file:///C|/DOCUME%7E1/senocular/LOCALS%7E1/Temp/Invalid XML URL

        at Timeline0_5650dafd68b564789d938267b772078/::frame1()

Ошибка возникла после выполнения trace("Continuing with script...").
В подобных случаях можно просто использовать обработчики событий.

Код:

var loader:URLLoader = new URLLoader();



loader.addEventListener(IOErrorEvent.IO_ERROR, catchIOError);

function catchIOError(event:IOErrorEvent){

    trace("Error caught: "+event.type);

}



loader.load(new URLRequest("Invalid XML URL"));

trace("Continuing with script...");

Результат:

Код:

Continuing with script...

Error caught: ioError

MerlinTwi

02.11.2006 19:58

4. Новые типы переменных

ActionScript 3 поддерживает широкий диапазон типов переменных, включая несколько отсутствующих в предыдущих версиях ActionScript. Основные типы для AS3:

Простые:

Boolean
int
null
Number
String
uint
undefined

Сложные:

Object
Array
Date
Error
Function
RegExp
XML
XMLList

Существуют также дополнительные типы, которые относятся к их классам; такие как : Matrix (flash.geom.Matrix), Shape (flash.display.Shape), URLRequest (flash.net.URLRequest), и т.д.

Примечание:

Специальный тип Void изменился в AS3 на слово в нижнем регистре (void, а не Void)
Новый тип * используется для обозначения любого типа данных. Рекомендуется использовать вместо опущенной информации о типе для ваших переменных.

Код:

var anything:*;
Тип XML - не то же самое, что и тип XML в ActionScript 1 и 2. Старый XML тип (object) теперь определен как XMLObject. XML теперь обозначает новый E4X-based XML объект.
int и uint - новые простые типы данных для целых (числа без дробной части) и unsigned integer (неотрицательные числа без дробной части). Могут быть полезны для значений, не подразумевающих дробные значения, как, например, итераторы цикла. В большинстве случаев использование типа данных int вместо Number обеспечит небольшое увеличение производительности, а uint лучше использовать только когда это необходимо, например для значений цвета.

MerlinTwi

02.11.2006 20:05

5. Отображаемые объекты (Display Objects)

ActionScript 3 пополнилась коллекция "отображаемых объектов", которые могут быть видимы на экране и добавлены в "display list".
Отображаемые объекты AS3 :

AVM1Movie
Bitmap
Loader
MorphShape*
MovieClip
Shape
SimpleButton
Sprite
StaticText*
TextField
Video

*Для ссылки на объекты существующие в timeline; вы не можете создавать их с помощью AS.

AVM1Movie представляет собой flash-ролик, созданный в ActionScript 1 или 2. Эти ролики используют ActionScript Virtual Maching 1, тогда как AS3 ролики используют AVM2. AVM2 ролики могут проигрывать ролики AVM1, но не могут взаимодействовать с ними (с их ActionScript) используя AS3.

Bitmaps - объекты bitmap. Вы можете задавать им изображение с помощью BitmapData объектов или это могут быть bitmap-картинки из файлов.

Объекты Loader - отображаемые объекты, которые загружают в себя внешнее содержимое. Это могут быть изображения или другие SWF-приложения.

MorphShapes - это shape tweens (анимации фигур), созданные на timeline. Хотя вы не можете создать их в ActionScript, вы можете получить доступ к уже существующим на timeline, используя ActionScript и они будут иметь тип MorphShape.

MovieClips - это ролики, которые вы знаете и любите.

Shapes это разобранные ролики, которые по существу содержат только graphics object для рисования в нем с использованием vector drawing API. Использование Shapes вместо MovieClips или Sprites может помочь сэкономить память

Sprite объекты - по существу ролики без timelines. Это наиболее часто используемый тип в AS3, и обычно он расширяется при создании вашего собственного подкласса отображаемых объектов.

StaticText, как и MorphShapes, не могут быть созданы в ActionScript, ссылаясь вместо этого на объекты static text, созданные на Flash timeline.

Объекты TextField включают dynamic и input text.

Объекты Video представляют Flash video.

MerlinTwi

02.11.2006 20:07

6. Новая директива Import

Директива import в ActionScript 3 немного отличается от import в ActionScript 2. В AS2 import использовался только для сокращения имен классов, определенных в пакетах; она не была обязательной для использования класса. Вместо использования import, вы могли просто использовать полное имя класса, например:

Код:

// ActionScript 2

var myPoint:flash.geom.Point = new flash.geom.Point(0,0);

В ActionScript 3, директива import обязательна для доступа к классам в их пакетах, даже если вы ссылаетесь на класс по его полному имени. Вы все еще можете использовать полное имя (или только проимпортированное имя класса), но использование import необходимо

Код:

// ActionScript 3

import flash.geom.Point;

var myPoint:flash.geom.Point = new flash.geom.Point(0,0);

Как и в AS2, в AS3 вы можете также использовать символ шаблона (*) для импорта всех классов в пакете.

Код:

import flash.geom.*;

MerlinTwi

02.11.2006 20:10

7. Приведение типов и оператор as

ActionScript позволяет заменить назначенный объекту тип на другой совместимый при необходимости. Это называется приведением (casting). Оба ActionScript 2 и 3 поддерживают приведение с использованием синтаксиса type(object). Например, если объект вашего класса был назначен переменной как object, вы можете переопределить типизацию для этого объекта приведением его к типу вашего класса, дав таким образом возможность Flash знать какие именно методы и свойства доступны у этого объекта

Код:

var obj:Object = getMyCustomObject();

var customObj:MyClass = MyClass(obj);

ActionScript 3 вводит новый оператор для приведения типов - оператор as. Оператор as заменяет приведение типа с использованием type(object) синтаксиса в ActionScript 2 на синтаксис object as type.

Код:

var obj:Object = getMyCustomObject();

var customObj:MyClass = obj as MyClass;

Оператор as работает весьма схоже с приведением в ActionScript 2. Если преобразование не может быть выполнено, его результат null. В противном случае приводимый объект возвращается и ему назначается указанный тип.

ActionScript 3 все еще поддерживает type(object) приведение, но его поведение имеет теперь некоторые отличия. Вместо возврата null при неправильном приведении, генерируется TypeError. Сбой происходит когда вы пытаетесь привести объект к несовместимому типу, например при попытке привести объект к не связанному (not associated) или унаследованному типу.

Примечание: ActionScript также имеет глобальные функции преобразования для этих целей в стиле Class(object), имеющие приоритет над приведением type(object). Это такие функции, как String(), Number(), Array() и т.д. Они не выполняют приведение настолько же как фактическое преобразование одного объекта в другой (когда это возможно). Т.к. эти функции приоритетнее type(object), предпочтительнее использовать оператор as для приведения объектов к другому типу данных.

MerlinTwi

02.11.2006 20:15

10. Ключевое слово delete и члены класса

Ключевое слово delete во Flash используется для удаления определений переменных. Оно не удаляет объекты из памяти (это происходит за кулисами с помощью так называемого "сборщика мусора" /"Garbage Collector"/ ), а просто берет созданную вами переменную и избавляется от нее, делая ее недоступной и невидимой для итераторов (for..in циклы, и т.п.).

Внутренние механизмы Garbage Collector (GC для краткости), знают когда физически удалять объекты из памяти - когда больше нет переменных, ссылающихся на них. Так, например, если у вас есть две переменные A и B и они обе ссылаются на ObjectX, удаление переменной A не приведет к удалению сборщиком мусора ObjectX из памяти. Однако, если вы удалите обе переменные A и B, больше не будет ссылок на ObjectX и GC будет знать, что объект нуждается в удалении из памяти

Код:

var a:Object = new Object();

var b:Object = a; // reference same new Object();

delete a;

trace(b); // [object Object] - still exists in memory

delete b;

// GC will mark object for deletion from memory

Этот механизм работает практически одинаково для Flash 8 и Flash 9 (ActionScript 1, 2, и 3), однако в 8 были сделаны некоторые изменения для оптимизации GC. (Примечание: GC очищает память не сразу.)

Хотя GC и новая виртуальная машина, управляющая им, на самом деле не сильно изменились в ActionScript 3, что изменилось, так это поведение ключевого слова delete. Теперь ключевое слово delete работает только для динамических свойств экземпляров класса, но не для объявленных членов класса (переменных и методов). В ActionScript 1 и 2 delete можно было использовать для всего. ActionScript 3 позволит только удалить динамические переменные и заблокирует прочее.

Код:

// ActionScript 2

class DeleteVarClass {

       

    public var myVar:Number;

   

    function DeleteVarClass() {

        myVar = 1;

        trace(myVar); // 1

        delete myVar;

        trace(myVar); // undefined

    }

}

Код:

// ActionScript 3

package {

    public class DeleteVarClass {

       

        public var myVar:Number;

           

        public function DeleteVarClass() {

            myVar = 1;

            trace(myVar); // 1

            delete myVar;

            trace(myVar); // 1

        }

    }

}

Поскольку myVar в примере выше был объявлен как свойство класса, он не может быть удален в ActionScript 3.

Поскольку вы не можете удалять члены класса в ActionScript 3, если вы хотите, чтобы переменная больше не ссылалась на объект или значение в памяти, вы можете установить значение переменной в null вместо ее удаления.

Код:

myVar = null;

MerlinTwi

02.11.2006 20:20

11. Класс Dictionary

Класс Dictionary (flash.utils.Dictionary) - новое дополнение в ActionScript. Он представляет собой то же самое, что и базовые объекты Object, за исключением одной особенности: в объектах Dictionary в качестве ключей могут быть использованы не только строки, но и любые другие значения.

Object использует только строковые ключи. Если в качестве для ключа используется не строковое значение, оно интерпретируется в строку.
Пример:

Код:

var obj:Object = new Object();

obj["name"] = 1; // string key "name"

obj[1] = 2; // key 1 (converted to "1")

obj[new Object()] = 3; // key new Object() converted to "[object Object]"



for (var prop:String in obj) {

     trace(prop); // traces: [object Object], 1, name

     trace(obj[prop]); // traces: 3, 2, 1

}

Если вы попытаетесь использовать разные объекты в качестве ключей для Object, которые одинаково преобразуются в строку, в контейнере это будет один и тот же ключ, ссылающийся на единственное значение.

Код:

var a:Object = new Object();

var b:Object = new Object();



var obj:Object = new Object();

obj[a] = 1; // obj["[object Object]"] = 1;

obj[b] = 2; // obj["[object Object]"] = 2;



for (var prop:String in obj) {

     trace(prop); // traces: [object Object]

     trace(obj[prop]); // traces: 2

}

Класс Dictionary подобного ограничения не имеет. В качестве ключа вы можете использовать любой тип. Таким образом, если в примере выше использовать Dictionary, вы получите два различных ключа, по одному для каждого объекта.

Код:

import flash.utils.Dictionary;



var a:Object = new Object();

var b:Object = new Object();



var dict:Dictionary = new Dictionary();

dict[a] = 1; // dict[a] = 1;

dict[b] = 2; // dict[b] = 2;



for (var prop:* in dict) {

     trace(prop); // traces: [object Object], [object Object]

     trace(dict[prop]); // traces: 1, 2

}

И несмотря на то, что вы все же получили [object Object] при трассировке, это просто результат строкового преобразования в команде trace; это уникальный объектный ключ в экземляре Dictionary.

Обратите внимание, что prop здесь определена как *. Это важно, т.к. ключи в объекте dict могут быть любого типа. Если вы используете String как тип prop, объекты a и b при их выборке в цикле будут приводиться к строкам, помещая в prop "[object Object]" вместо действительных ссылок на a и b, которыми они должны быть для корректного доступа к значениям 1 и 2 из dict.

MerlinTwi

02.11.2006 20:23

12. Метки

В ActionScript 3 введены метки (url=http://livedocs.macromedia.com/flex/2/langref/statements.html#label]labels[/url]), новые идентификаторы, которые можно привязывать к блокам циклов. Зачем вам может понадобиться идентифицировать блок цикла? Потому, что этот идентификатор можно использовать в командах break и continue. Представьте себе два цикла, один вложен в другой. Если в какой-то момент вы захотите прервать оба цикла, находясь во внутреннем, вы этого сделать не сможете. Команда break прервет только текущий блок. Обычно для этих целей используют переменную-флаг, которую устанавливают во внутреннем цикле, чтобы иметь возможность проверить во внешнем и, при необходимости, выйти также и из него. Пример:

Код:

var i:Number;

var j:Number;

var exit:Boolean = false;

for (i=0; i<10; i++) {

    for (j=0; j<10; j++) {

        if (i > 3 && j > 3) {

            exit = true;

            break;

        }

    }

    if (exit) {

        break;

    }

}

Когда i больше 3 и j больше 3, используется break для выхода из текущего цикла, но это выход только из цикла по j. Для того, чтобы выйти и из цикла i, была использована переменная exit с условным оператором if в цикле по i.

Метки позволяют вам идентифицировать и прерывать указанный цикл (а также все вложенные в него). Формат метки label: statement
Пример:

Код:

var i:Number;

var j:Number;

mainLoop: for (i=0; i<10; i++) {

    for (j=0; j<10; j++) {

        if (i > 3 && j > 3) {

            break mainLoop;

        }

    }

}

Задав для первого цикла метку mainLoop, мы получили возможность легко прервать вложенный цикл, используя break mainLoop; Это позволяет писать более понятный код и избавляет от необходимости использовать дополнительные переменные.

Часовой пояс GMT +4, время: 03:49.

Страница 9 из 13

Показывать 40 сообщений этой темы на одной странице

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.