Система диалогов, создаем подобие old School типа Fallout.

<?xml version="1.0" encoding="utf-8" ?>
<data>

	<person name = "James">
		<dialog title = "Эй бро, как делишки?">
			<line title = "Здорова, все ок." lock = "false" id = "1">
				<dialog title = "Куда напрвляешься?">
					<line title = "Eду в СПБ." lock = "false" id = "10" >
						<dialog title = "Ну удачи бро.">
							<line title = "Бывай!" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "Хреново!" lock = "false" id = "2">
				<dialog title = "Да не ссы ты, я сто раз так делал!!!">
					<line title = "Ладно, но с тебя пивас!" lock = "false" id = "11">
						<dialog title = "Заметано.">
							<line title = "Бывай!" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "Да пошел ты!" lock = "false" id = "3">
				<dialog title = "Heh Fuck Himself!">
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>	
			<line title = "[Выход]" lock = "false" id = "0"/>
		</dialog>		
	</person>
	
	<person name = "Гнусный Орк">
		<dialog title = "Бурлы мурлы, моя твоя не понимать...моя садись, твоя поехали...">
			<line title = "Ты кто такой?" lock = "false" id = "1">
				<dialog title = "Моя друг человека!">
					<line title = "Я слежу за тобой..." lock = "false" id = "10" lockedid = "2">
						<dialog title = "Да-да следить, следить...">
							<line title = "[Про себя : ну и мурло же ты][Выход]" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "Выходи сражаться исчадие ада!" lock = "false" id = "2">
				<dialog title = "[Орк сопит] Я боюсь тебя человека!">
					<line title = "[достать незаметно нож] А ты не бойся, сейчас мы подружимся!" lock = "false" id = "11">
						<dialog title = "Дружить, давай дружить!">
							<line title = "[Напасть]" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "[Грозно зарычать на орка]" lock = "false" id = "3">
				<dialog title = "[Орк испугался и убежал]">
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>	
			<line title = "[Выход]" lock = "false" id = "0"/>
		</dialog>		
	</person>
	
	<person name = "Гнусный Орк с пушкой из НКР">
		<dialog title = "Бурлы мурлы, моя твоя не понимать...моя садись, твоя поехали...">
			<line title = "Ты кто такой?" lock = "false" id = "1">
				<dialog title = "Моя друг человека!">
					<line title = "Я слежу за тобой..." lock = "false" id = "10">
						<dialog title = "Да-да следить, следить...">
							<line title = "[Про себя : ну и мурло же ты][Выход]" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "Выходи сражаться исчадие ада!" lock = "false" id = "2">
				<dialog title = "[Орк сопит] Я боюсь тебя человека!">
					<line title = "[достать НЕЗАМЕТНО бозар] А ты не бойся, сейчас мы подружимся!" lock = "false" id = "11" lockedperson = "Гнусный Орк с пушкой из НКР_connected" lockedpersonid = "11">
						<dialog title = "Дружить, давай дружить!">
							<line title = "[Напасть]" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "[Грозно зарычать на орка]" lock = "false" id = "3">
				<dialog title = "[Орк испугался и убежал]">
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>	
			<line title = "[Выход]" lock = "false" id = "0"/>
		</dialog>		
	</person>
	
	<person name = "Гнусный Орк с пушкой из НКР_connected">
		<dialog title = "Бурлы мурлы, моя твоя не понимать...моя садись, твоя поехали...">
			<line title = "Ты кто такой?" lock = "false" id = "1">
				<dialog title = "Моя друг человека!">
					<line title = "Я слежу за тобой..." lock = "false" id = "10">
						<dialog title = "Да-да следить, следить...">
							<line title = "[Про себя : ну и мурло же ты][Выход]" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "Выходи сражаться исчадие ада!" lock = "false" id = "2">
				<dialog title = "[Орк сопит] Я боюсь тебя человека!">
					<line title = "[достать НЕЗАМЕТНО бозар] А ты не бойся, сейчас мы подружимся!" lock = "false" id = "11">
						<dialog title = "Дружить, давай дружить!">
							<line title = "[Напасть]" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "[Грозно зарычать на орка]" lock = "false" id = "3">
				<dialog title = "[Орк испугался и убежал]">
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>	
			<line title = "[Выход]" lock = "false" id = "0"/>
		</dialog>		
	</person>

</data>

Код AS3:

package admin.models 
{
	/**
	 * ...
	 * @author in4core progression lab
	 */
	public class DialogsStatic 
	{
		private static var _dialogs:XML = null;
 
		public static function insertDialogs(xml:XML):void
		{
			_dialogs = xml;
		}
 
		public static function getDialogsByPersonName(id:String):XMLList
		{
			return _dialogs.person.(@name == id)
		}
	}
}

Код AS3:

package admin.views 
{
	import admin.models.PersonModel;
	import flash.display.Sprite;
	import flash.events.Event;
 
	/**
	 * ...
	 * @author in4core progression lab
	 */
	public class PersonView extends Sprite 
	{
		private var _model:PersonModel;
 
		public function PersonView(model:PersonModel) 
		{
			this._model = model;
 
			addEventListener(Event.ADDED_TO_STAGE , onAdded);
		}
 
		private function onAdded(e:Event):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, onAdded);
 
			graphics.beginFill(0x0);
			graphics.drawRect(0, 0, 50, 50);
		}
 
		public function get model():PersonModel 
		{
			return _model;
		}
 
	}
 
}

Код AS3:

package admin.models 
{
	import flash.events.EventDispatcher;
 
	/**
	 * ...
	 * @author in4core progression lab
	 */
	public class PersonModel extends EventDispatcher 
	{
		private var _name:String = "default";
		private var _dialogues:XMLList = null;
 
		public function PersonModel() 
		{
 
		}
 
		public function get isSpeakable():Boolean
		{
			if (_dialogues) return true;
 
			return false;
		}
 
		public function get name():String 
		{
			return _name;
		}
 
		public function set name(value:String):void 
		{
			_name = value;
		}
 
		public function get dialogues():XMLList 
		{
			return _dialogues;
		}
 
		public function set dialogues(value:XMLList):void 
		{
			_dialogues = value;
		}
 
	}
 
}

Код AS3:

private function onAdded(e:Event):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, onAdded);
 
			var xml:XML = new XML( new _xmls() );
 
			DialogsStatic.insertDialogs( xml );
 
			var model:PersonModel = new PersonModel();
			model.name = "James";
			model.dialogues = DialogsStatic.getDialogsByPersonName(model.name);
			var person:PersonView = new PersonView(model);
			person.addEventListener(MouseEvent.CLICK , createDialog);
 
			this.addChild(person);
		}

<?xml version="1.0" encoding="utf-8" ?>
<data>

	<person name = "James">
		<dialog title = "Эй бро, как делишки?">
			<line title = "Здорова, все ок." lock = "false" id = "1">
				<dialog title = "Куда напрвляешься?">
					<line title = "Eду в СПБ." lock = "false" id = "10" >
						<dialog title = "Ну удачи бро.">
							<line title = "Бывай!" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "Хреново!" lock = "false" id = "2">
				<dialog title = "Да не ссы ты, я сто раз так делал!!!">
					<line title = "Ладно, но с тебя пивас!" lock = "false" id = "11">
						<dialog title = "Заметано.">
							<line title = "Бывай!" lock = "false" id = "0"/>
							<line title = "[Выход]" lock = "false" id = "0"/>
						</dialog>
					</line>
					<line title = "[Назад]" lock = "false" id = "-1"/>
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>
			<line title = "Да пошел ты!" lock = "false" id = "3">
				<dialog title = "Heh Fuck Himself!">
					<line title = "[Выход]" lock = "false" id = "0"/>
				</dialog>
			</line>	
			<line title = "[Выход]" lock = "false" id = "0"/>
		</dialog>		
	</person>
</data>

Код AS3:

package admin.views 
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	/**
	 * ...
	 * @author in4core progression lab
	 */
	public class DialogView extends Sprite 
	{
 
		public function DialogView() 
		{
			addEventListener(Event.ADDED_TO_STAGE , onAdded);
		}
 
		private function onAdded(e:Event):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, onAdded);
 
			graphics.beginFill(0xAA0000);
			graphics.drawRect(0, 0, 600 , 200);
			graphics.beginFill(0x880000);
			graphics.drawRect(1, 1, 598 , 198);
		}
 
		public function createDialog( list : XMLList , name : String ):void
		{
			this.removeChildren();
 
			var header:DialogLine = new DialogLine();
			header.create(name + " : " + list.@title , null);
			addChild(header);
 
			header.x = 10;
			header.y = 10;
 
			var lst:XMLList = list.line.(@lock == false);
 
			for (var i:int = 0; i < lst.length(); i++)
			{
				var line:DialogLine = new DialogLine();
 
				line.create( (i+1) + ". " + lst[i].@title, lst[i].@id); 
 
				addChild(line);
 
				line.y = line.height * i + header.height + 20;
				line.x = 10;
			}
		}
 
		public function destroyDialog():void 
		{
			this.removeChildren();
		}
	}
}

Код AS3:

package admin.views 
{
	import admin.utils.DialogsEvents;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.text.TextField;
 
	/**
	 * ...
	 * @author in4core progression lab
	 */
	public class DialogLine extends Sprite 
	{
		private var _field:TextField = new TextField();
		private var _id:String = null;
 
		public function DialogLine() 
		{
			super();
			addChild(this._field);
		}
 
		public function create(text:String , id:String):void
		{
			this._id = id;
 
			this._field.text = text;
			this._field.width = this._field.textWidth + 5;
			this._field.height = 30;
			this._field.selectable = false;
 
			if (id != null) 
			{
				this._field.textColor = 0xFF0000;
				this._field.addEventListener(MouseEvent.CLICK , lineSelected);
				this._field.addEventListener(MouseEvent.MOUSE_OVER , onOver);
				this._field.addEventListener(MouseEvent.MOUSE_OUT , onOut);
			}
			else 
			{
				this._field.textColor = 0xFFFFFF;
			}
		}
 
		private function onOut(e:MouseEvent):void 
		{
			this._field.textColor = 0xFF0000;
		}
 
		private function onOver(e:MouseEvent):void 
		{
			this._field.textColor = 0xFFFF00;
		}
 
		private function lineSelected(e:MouseEvent):void 
		{
			this.dispatchEvent(new DialogsEvents(DialogsEvents.LINE_SELECTED , _id , true));
		}
 
		public function get id():String 
		{
			return this._id;
		}
 
	}
 
}

Код AS3:

package admin.controllers 
{
	import admin.models.PersonModel;
	import admin.utils.DialogsEvents;
	import admin.views.DialogView;
	import flash.events.EventDispatcher;
 
	/**
	 * ...
	 * @author in4core progression lab
	 */
	public class DialogManager extends EventDispatcher 
	{
		private var _model:PersonModel;
 
		private var _lastDialog:Vector.<XMLList> = new Vector.<XMLList>();
		private var _curDialog:XMLList;
		private var _personModels:Vector.<PersonModel> = new Vector.<PersonModel>();
 
		public function DialogManager() 
		{
 
		}
 
		public function addModel(model:PersonModel):void
		{
			this._personModels.push(model);
		}
 
		public function changeConnectedDialog(name:String , id:String) : void
		{
			for (var i:int = 0; i < this._personModels.length; i++)
			{
				if (this._personModels[i].name == name)
				{
					this._personModels[i].dialogues..*.line.(@id == id).@lock = true;
				}
			}
		}
 
		public function connect(model:PersonModel):void
		{
			this._model = model;
			this._lastDialog = new Vector.<XMLList>();
			this._curDialog = model.dialogues.dialog;
			this._lastDialog.push(this._curDialog);
		}
 
		public function getCurrentDialog():XMLList
		{
			return this._curDialog;
		}
 
		public function logic(id:String):void 
		{
			checkInLock(id);
			checkInConnected(id);
 
			if (id == "0") 
			{
				this.dispatchEvent(new DialogsEvents(DialogsEvents.CLOSE_DIALOG));
			}
			else if (id == "-1")
			{
				this._curDialog = this._lastDialog[this._lastDialog.length - 1];
				this._lastDialog.pop();
				this.dispatchEvent(new DialogsEvents(DialogsEvents.DIALOG_LEVEL_CHANGED));
			}
			else 
			{
				this._lastDialog.push(this._curDialog);
				this._curDialog = this._curDialog.line.(@id == id).dialog;
				this.dispatchEvent(new DialogsEvents(DialogsEvents.DIALOG_LEVEL_CHANGED));
			}
		}
 
		private function checkInConnected(id:String):void 
		{
			var search:String = this._model.dialogues..*.line.(@id == id).@lockedperson;
			var ids:String = this._model.dialogues..*.line.(@id == id).@lockedpersonid;
 
			if ( search != "" )
			{
				dispatchEvent(new DialogsEvents(DialogsEvents.CONNECTED_PERSONS , [ search , ids ]));
 
				changeConnectedDialog(search , ids);
			}
		}
 
		private function checkInLock(id:String):void 
		{
			var search:String = this._model.dialogues..*.line.(@id == id).@lockedid;
 
			if ( search != "" )
			{
				this._model.dialogues..*.line.(@id == search).@lock = true;
 
				for (var i:int = 0 ; i < this._lastDialog.length; i++)
				{
					this._lastDialog[i]..*.line.(@id == search).@lock = true;
				}
 
			}
		}
 
		public function get model():PersonModel 
		{
			return _model;
		}
	}
}

Код AS3:

package admin.views 
{
	import admin.controllers.DialogManager;
	import admin.models.BaseModel;
	import admin.models.DialogsStatic;
	import admin.models.PersonModel;
	import admin.utils.DialogsEvents;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	/**
	 * ...
	 * @author in4core progression lab
	 */
	public final class BaseView extends Sprite 
	{
		[Embed(source = "../../../bin/dialogs.xml", mimeType="application/octet-stream")] private var _xmls:Class;
 
		private var _baseModel:BaseModel;
		private var _dview:DialogView = new DialogView();
		private var _dmanager:DialogManager = new DialogManager();
 
		public function BaseView() 
		{
			addEventListener(Event.ADDED_TO_STAGE, onAdded);
		}
 
		public function set baseModel(model:BaseModel):void
		{
			this._baseModel = model;
		}
 
		private function onAdded(e:Event):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, onAdded);
 
			var xml:XML = new XML( new _xmls() );
 
			DialogsStatic.insertDialogs( xml );
 
			addChild(this._dview);
			this._dview.y = stage.stageHeight - this._dview.height - 20;
			this._dview.x = stage.stageWidth / 2 - this._dview.width / 2;
 
			this._dview.addEventListener(DialogsEvents.LINE_SELECTED , onDialogLineSelected);
			this._dmanager.addEventListener(DialogsEvents.DIALOG_LEVEL_CHANGED , onUpdateDialogLevel);
			this._dmanager.addEventListener(DialogsEvents.CLOSE_DIALOG , onDialogCloses);
			this._dmanager.addEventListener(DialogsEvents.CONNECTED_PERSONS , onConnectedPersons);
 
			var model:PersonModel = new PersonModel();
			model.name = "James";
			model.dialogues = DialogsStatic.getDialogsByPersonName(model.name);
			var person:PersonView = new PersonView(model);
			person.addEventListener(MouseEvent.CLICK , createDialog);
 
			this.addChild(person);
 
			var model1:PersonModel = new PersonModel();
			model1.name = "Гнусный Орк";
			model1.dialogues = DialogsStatic.getDialogsByPersonName(model1.name);
			var person1:PersonView = new PersonView(model1);
			person1.addEventListener(MouseEvent.CLICK , createDialog);
 
			this.addChild(person1);
 
			person1.x = 100;
 
			var model2:PersonModel = new PersonModel();
			model2.name = "Гнусный Орк с пушкой из НКР";
			model2.dialogues = DialogsStatic.getDialogsByPersonName(model2.name);
			var person2:PersonView = new PersonView(model2);
			person2.addEventListener(MouseEvent.CLICK , createDialog);
 
			this.addChild(person2);
 
			person2.x = 200;
 
			var model3:PersonModel = new PersonModel();
			model3.name = "Гнусный Орк с пушкой из НКР_connected";
			model3.dialogues = DialogsStatic.getDialogsByPersonName(model3.name);
			var person3:PersonView = new PersonView(model3);
			person3.addEventListener(MouseEvent.CLICK , createDialog);
 
			this.addChild(person3);
 
			person3.x = 300;
 
			this._dmanager.addModel(model2);
			this._dmanager.addModel(model3);
		}
 
		private function onConnectedPersons(e:DialogsEvents):void 
		{
 
		}
 
		private function onDialogCloses(e:DialogsEvents):void 
		{
			this._dview.destroyDialog();
		}
 
		private function onUpdateDialogLevel(e:DialogsEvents):void 
		{
			this._dview.createDialog( this._dmanager.getCurrentDialog() , this._dmanager.model.name );
		}
 
		private function onDialogLineSelected(e:DialogsEvents):void 
		{
			this._dmanager.logic(e.params as String);
		}
 
		private function createDialog(e:MouseEvent):void 
		{
			const person:PersonView = e.currentTarget as PersonView;
			const model:PersonModel = person.model;
			this._dmanager.connect(model);
			onUpdateDialogLevel(null);
		}
	}
 
}