Идиотизмы: кто мой папа?

Код AS3:

package { 
 
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.text.TextField;
 
    public class test extends Sprite {
 
        public function test() {
            super();
            var t:TextField = new TextField();
            t.addEventListener( Event.ADDED, this.handler_addedToStage )
            t.width = 400;
            t.height = 200;
            t.htmlText = ' <' + 'img src="http://www.google.ru/logos/olympics10-hockey-hp.png" />';
            super.addChild( t );
        }
 
        private function handler_addedToStage(event:Event):void {
            if ( event.target == event.currentTarget ) return;
            trace( event.target );
        }
 
    }
 
}

[object Loader]
[object Sprite]

Код AS3:

package blooddy.patch.text {
 
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.text.TextField;
 
    /**
     * @author              BlooDHounD
     * @playerversion       Flash 9
     * @langversion         3.0
     */
    public class TextField extends flash.text.TextField {
 
        //--------------------------------------------------------------------------
        //
        //  Constructor
        //
        //--------------------------------------------------------------------------
 
        /**
         * Constructor
         */
        public function TextField() {
            super();
            super.addEventListener( Event.ADDED,   this.handler_added,   false, int.MAX_VALUE, true );
            super.addEventListener( Event.REMOVED, this.handler_remvoed, false, int.MAX_VALUE, true );
        }
 
        //--------------------------------------------------------------------------
        //
        //  Event handlers
        //
        //--------------------------------------------------------------------------
 
        /**
         * @private
         */
        private function handler_added(event:Event):void {
            if ( event.target !== this ) {
                // останавливаем расспостранение события
                // наши родители даже не догадываются о его существовании
                event.stopImmediatePropagation();
                // если пришёл Loader, то надо подписаться на всяческие ошибки
                if ( event.target is Loader ) {
                    // так как мы не собираемся контролировать объект, лучше подпишимся со слабыми ссылками
                    var loader:LoaderInfo = ( event.target as Loader ).contentLoaderInfo;
                    loader.addEventListener( Event.COMPLETE,        this.handler_complete, false, int.MAX_VALUE, true );
                    loader.addEventListener( IOErrorEvent.IO_ERROR, this.handler_complete, false, int.MAX_VALUE, true );
                }
            }
        }
 
        /**
         * @private
         */
        private function handler_remvoed(event:Event):void {
            if ( event.target !== this ) {
                // останавливаем расспостранение события
                // наши родители даже не догадываются о его существовании
                event.stopImmediatePropagation();
                // если пришёл Loader, то надо отписаться на всяческие ошибки
                if ( event.target is Loader ) {
                    // отписываемся
                    var loader:LoaderInfo = ( event.target as Loader ).contentLoaderInfo;
                    loader.removeEventListener( Event.COMPLETE,        this.handler_complete );
                    loader.removeEventListener( IOErrorEvent.IO_ERROR, this.handler_complete );
                }
            }
        }
 
        /**
         * @private
         */
        private function handler_complete(event:Event):void {
            var loader:LoaderInfo = event.target as LoaderInfo;
            loader.removeEventListener( Event.COMPLETE,        this.handler_complete );
            loader.removeEventListener( IOErrorEvent.IO_ERROR, this.handler_complete );
        }
 
    }
 
}